解决 NixOS + Home Manager 的 VSCode settings.json 写入问题

1
# ./home/linux/gui/vscode.nix
2
{
3
  config,
4
  lib,
5
  pkgs,
6
  ...
7
}: let
8
  inherit (lib.lists) concatLists;
9
10
  homeDir = config.home.homeDirectory;
11
  userDataDir = "${homeDir}/.data/vscode/data";
12
  extensionsDir = "${homeDir}/.data/vscode/extensions";
13
14
  pkg = pkgs.vscode.override {
15
    commandLineArgs = concatLists [
16
      ["--extensions-dir" extensionsDir]
17
      ["--user-data-dir" userDataDir]
18
    ];
19
  };
20
in {
21
  imports = [./profiles];
22
23
  programs.vscode = {
24
    enable = true;
25
    package = pkg;
26
    mutableExtensionsDir = false;
27
  };
28
29
  # To solve VSCode wants to write settings.json
30
  # VSCode will reset per reboot/rebuild.
31
  systemd.user.services.vscode-setup = {
32
    Unit = {
33
      Description = "VSCode Setup service";
34
      After = ["graphical-session-pre.target"];
35
      Wants = ["graphical-session-pre.target"];
36
    };
37
    Install.WantedBy = ["graphical-session.target"];
38
    Service = {
39
      Type = "oneshot";
40
      ExecStart = lib.getExe (pkgs.writeShellApplication {
41
        name = "vscode-setup";
42
        text = ''
43
          rm -rf "${userDataDir}/User"
44
          rm -rf "${extensionsDir}"
45
46
          mkdir -p "${userDataDir}"
47
          mkdir -p "${extensionsDir}"
48
49
          cp -r --dereference --no-preserve=mode,ownership \
50
            "${homeDir}/.config/Code/User" "${userDataDir}/User"
51
          cp -r --dereference --no-preserve=mode,ownership \
52
            "${homeDir}/.vscode/extensions/." "${extensionsDir}"
53
        '';
54
      });
55
    };
56
  };
57
}

1
# ./home/linux/gui/vscode.nix
2
{
3
  config,
4
  lib,
5
  pkgs,
6
  ...
7
}: let
8
  homeDir = config.home.homeDirectory;
9
  dataDir = config.xdg.dataHome;
10
  userDataDir = "${dataDir}/vscode/data";
11
  extensionsDir = "${dataDir}/vscode/extensions";
12
in {
13
  programs.vscode = {
14
    enable = true;
15
    mutableExtensionsDir = false;
16
  };
17
18
  # To solve VSCode wants to write settings.json
19
  # VSCode will reset per reboot/rebuild.
20
  systemd.user.services.vscode-setup = {
21
    Unit = {
22
      Description = "VSCode Setup service";
23
      After = ["graphical-session-pre.target"];
24
      Wants = ["graphical-session-pre.target"];
25
    };
26
    Install.WantedBy = ["graphical-session.target"];
27
    Service = {
28
      Type = "oneshot";
29
      UMask = "0022";
30
      ExecStart = lib.getExe (pkgs.writeShellApplication {
31
        name = "vscode-setup";
32
        runtimeInputs = with pkgs; [coreutils gnutar jq];
33
        text = let
34
          userSrc = "${homeDir}/.config/Code/User";
35
          userDst = "${userDataDir}/User";
36
          extSrc = "${homeDir}/.vscode/extensions";
37
          extDst = extensionsDir;
38
39
          dirsToPreserve = [
40
            "workspaceStorage"
41
            "History"
42
          ];
43
          backupCmds = builtins.concatStringsSep "\n" (map (dir: ''
44
              if [ -e "${userDst}/${dir}" ]; then
45
                echo "Backing up data/User/${dir}..."
46
                mv "${userDst}/${dir}" "/tmp/vscode-${dir}-$$"
47
              fi
48
            '')
49
            (dirsToPreserve ++ ["globalStorage"]));
50
          restoreCmds = builtins.concatStringsSep "\n" (map (dir: ''
51
              if [ -e "/tmp/vscode-${dir}-$$" ]; then
52
                echo "Restoring data/User/${dir}..."
53
                mv "/tmp/vscode-${dir}-$$" "${userDst}/${dir}"
54
              fi
55
            '')
56
            dirsToPreserve);
57
        in ''
58
          set -eu
59
60
          ${backupCmds}
61
62
          echo "Cleaning old directories..."
63
          rm -rf "${userDst}"
64
          rm -rf "${extDst}"
65
66
          mkdir -p "${userDataDir}"
67
          mkdir -p "${extDst}"
68
69
          echo "Copying user settings from ${userSrc}..."
70
          cp -r --dereference --no-preserve=mode,ownership ${userSrc} "${userDst}"
71
72
          echo "Copying extensions from ${extSrc}..."
73
          tar -h -C "${extSrc}" -cf - . | tar -C "${extDst}" -xf - --no-same-owner --no-same-permissions --mode='u=rX,go=rX'
74
          chmod u+w -R "${extDst}" 2>/dev/null || true
75
76
          ${restoreCmds}
77
78
          echo "Restoring and merging data/User/globalStorage..."
79
          if [ -e "/tmp/vscode-globalStorage-$$" ]; then
80
            cp -rT "/tmp/vscode-globalStorage-$$" "${userDst}/globalStorage"
81
82
            src_storage_json="${userSrc}/globalStorage/storage.json"
83
            dst_storage_json="${userDst}/globalStorage/storage.json"
84
85
            if [ -f "$src_storage_json" ] && [ -f "$dst_storage_json" ]; then
86
              echo "Merging data/globalStorage/storage.json with new data..."
87
              merged_json=$(mktemp)
88
              jq -s '.[0] * .[1]' "$dst_storage_json" "$src_storage_json" > "$merged_json"
89
              mv "$merged_json" "$dst_storage_json"
90
              echo "Merge complete."
91
            else
92
              echo "Skipping storage.json merge: one or both files do not exist."
93
            fi
94
          else
95
            echo "No backed-up globalStorage found to restore."
96
          fi
97
98
          echo "VSCode setup complete."
99
        '';
100
      });
101
    };
102
  };
103
}